The Gorreven Papers — 19 of 23

Section 18 - The Kennels

The Kennels are east of the Barracks. "[if the Kennels are unvisited]As you enter the room you have to duck because the ceiling is only five and a half feet tall. Clearly this is an area not often entered by humans. All around you, hideous demonic dogs[unicode em dash]Rottweilers, Dobermans, pit bulls, and German Shepherds[unicode em dash]are snarling and biting the bars of their cages. They're looking at you with bloodlust in their eyes; they know there's something wrong about you. Maybe they've been taught your scent.[otherwise]You're crouching within the low-roofed kennels.[end if] To the west are the barracks. Down the north side of the room are rows of cages containing the vicious dogs. The dogs are all fed automatically; ducts extend from a big hopper on the east side of the kennels into each dog's dish in its cage. The cages all have doors on the north side, leading out into the courtyard. Presumably this is for quickly releasing the dogs if an intruder gets in[if the Kennels are unvisited][unicode em dash]or gets out. Something to think about when you're trying to escape[end if]."

Some cages are an openable container in the Kennels. They are fixed in place and transparent. They are closed. Some dogs are in the cages. The dogs can be alive or dead. The dogs are alive. The description of the dogs is "a pack of[if the dogs are dead] dead[end if]dogs". The dogs can be confined or released. The dogs are confined.

Rule for writing a paragraph about the cages:

now the cages are mentioned.

Instead of opening the cages:

say "They don't open from this side."

Instead of entering the cages:

say "You can't get in from this side."

The hopper is a container in the Kennels. It is fixed in place and transparent.

The dog food is in the hopper. The indefinite article is "some". The dog food can be poisoned or nutritious. It is nutritious.

The big red button is in the Kennels. It is fixed in place.

Instead of examining the big red button:

say "Beneath it, stenciled in the metal, it reads: 'PUSH TO FEED.'"

Instead of pushing the red button when the dog food is not in the hopper:

say "Machinery grinds noisily but nothing happens; the hopper is empty."

Instead of pushing the red button when the dog food is in the hopper:

say "There is a clanking sound of machinery; the level of dog food in the hopper drops as the dog food pours into the individual dishes in the kennels. The dogs forget you and start eating ravenously. [run paragraph on]";

if the dog food is poisoned:

say "It's pretty potent poison; within minutes they are dead. All of them.";

now the dogs are dead;

otherwise:

say "They lick their lips and grumble with satisfaction. Yet even after this they still look like they want to kill you.";

now the the dog food is nowhere.

Instead of putting the poison on the dog food:

try pouring the poison onto the dog food.

After pouring the poison onto the cages:

say "The dogs sniff at it suspiciously. They don't seem to like its smell, and they growl at you suspciously and then back away. Not one of them takes a taste. After a moment the puddle of poison evaporates and is gone."

After pouring the poison onto:

say "After a moment all traces of the poison are gone.";

if the second noun is the dog food or the second noun is the hopper:

now the dog food is poisoned;

otherwise if the second noun is the dogs:

say "The poison has only splattered onto a few of the most curious ones, close to the cage bars. They sneeze and lick at their fur. A minute later they choke, stiffen, and die. The remaining dogs keep their distance, growling at the bodies, and at you."

Instead of examining the dogs:

if the dogs are alive:

say "They are snarling furiously, saliva dripping from their jaws.";

otherwise:

say "They are all lying stiffly in various contorted poses. All dead."

Proximity is a kind of value. The proximities are upon you, imminent, approaching, and distant. The dogs have a proximity. The proximity of the dogs is distant.

Every turn when the dogs are alive and the dogs are released:

if the dogs are upon you:

say "The dogs are at your heels. You cannot run fast enough. They have you. Within seconds you are buried under a snarling, salivating canine chaos[unicode em dash]they all want a piece of you, and that's just what's happening. The pain and fear is tremendous and your only consolation is that it does not last long.";

end the story finally;

otherwise if the dogs are imminent:

say "A pack of snarling dogs bursts in upon you!";

[Do this only so that the player might futilely examine or shoot the dogs right before they attack.]

move the dogs to the location of the player;

otherwise:

if the dogs are approaching:

say "In the distance you hear dogs baying.";

now the dogs are the proximity before the proximity of the dogs.

Before attacking the dogs:

if the dogs are dead:

say "They're all dead.";

stop the action.

Instead of shooting the dogs:

try attacking the dogs.

Instead of attacking the dogs when the player carries the pistol:

if the shot count of the pistol is zero:

say "You beat at their heads with the butt of your unloaded gun. [run paragraph on]";

otherwise:

say "You pump your remaining ammunition into the pack. [run paragraph on]";

now the shot count of the pistol is zero;

if the dogs are released:

say "But it's just not enough. The pack overwhelms you, tearing out chunks of your flesh, crunching your bones[unicode ellipsis]fortunately it does not last long.";

end the story finally;

otherwise:

say "But it only kills a few. There are far too many others left alive, and the deaths do not subdue them but rather make them all the more furious."

Instead of attacking the dogs:

if the dogs are released:

say "You reach for the throat of the lead dog with a vague idea of choking it somehow. But the dog's neck feels like it's made of solid muscle. It hurls itself at you and bears you to the ground in a single motion, jaws clamped viselike around your right wrist. The rest of the pack joins in a fury. You don't last long, which is a small mercy.";

end the story finally;

otherwise:

say "You can't quite reach them through the bars. They all retreat to the far corners of their cages and snarl at you.".