The Gorreven Papers — 20 of 23

Section 19 - The Guard Tower

The Guard Tower is a room. "You're in the top of a tall guard tower that overlooks the entire aboveground part of the complex. There are wide windows in all four directions, glassless openings in the walls. A breeze blows through the room, keeping it cold."

An object can be windowlike. An object is usually not windowlike.

Some windows are scenery in the Guard Tower. They are windowlike.

Looking out of is an action applying to one visible thing.

Understand "look out of [something]" as looking out of.

Understand "look out [something]" as looking out of.

Check looking out of:

if the noun is windowlike:

continue the action;

otherwise:

say "That's not something you can look out of.";

stop the action.

Carry out looking out of the windows:

say "You can see a twelve-foot chain-link fence extending all around the perimeter of the complex. Beyond the fence, to the north only, is a dense woods. If you can get into that woods they will never catch you.[paragraph break]To the south you see a guarded entrance. Beyond it there is a wide expanse of gently rolling ground and a paved road. You'll have to go a long way before being able to hide yourself in that direction.[paragraph break]To the east you can see what appear to be kennels, probably for attack dogs. Closer to the guard tower itself is a structure that is probably the barracks. Beyond the east fence is a wide, flat plain with nowhere to hide.[paragraph break]Beyond the west fence you see a muddy, shallow river that issues from the north woods. Beyond the river there is only flat, open ground. The woods to the north look more promising. Next to the guard tower is a building that looks like a warehouse."

Instead of examining the windows, try looking out of the windows.

Instead of searching the windows, try looking out of the windows.

A powerful searchlight is in the Guard Tower. It is fixed in place. It is glasslike. It is gunworthy. The searchlight can be working or broken. It is working.

Understand "light" as the searchlight.

[Inform gets confused by the permutations of tower, guard, etc. when setting this up, so I gave the tower guard a name. But I don't like the approach. Documentation suggests using the phrase "called" to help. But that didn't help.]

Grubnok is an ordinary guard. Grubnok is in the Guard Tower.

Rule for writing a paragraph about Grubnok:

if Grubnok is dead:

say "The corpse of the late tower guard slumps against the wall.";

otherwise:

say "A tower guard paces slowly from one corner of the room to the next, his boot leather creaking.";

now Grubnok is mentioned.

Understand "tower guard" as Grubnok.

Every turn when the player is in the Guard Tower and the searchlight is broken:

if the player can see a guard (called the sentry) and the sentry is alive:

say "The guard whirls around. 'What do you think you're doing?' he demands. He suddenly looks you right in the eye.";

now the sentry is mentioned;

now the sentry is panicked.

Instead of examining the searchlight:

say "The base of the light appears to contain large backup batteries, so it can function even in a power outage. The light is fastened to the floor, made so that it can swivel around and shine its powerful beam out any one of the window openings[if the searchlight is broken]. It also happens to be broken beyond any simple repair[end if]."

Carry out shooting the searchlight:

say "You fire at the searchlight with [the pistol]. [run paragraph on]";

say "The glass and the bulb shatter into fragments which go flying everywhere.";

now the searchlight is broken;

now the searchlight is not gunworthy.

Carry out smashing the searchlight with:

say "The glass and the bulb shatter into fragments which go flying everywhere.";

now the searchlight is broken;

now the searchlight is not gunworthy.