The Gorreven Papers — 4 of 23

Section 3 - Of Guards and Guns

Shooting is an action applying to one visible thing. Understand "shoot [something]" as shooting. An object can be gunworthy. An object is usually not gunworthy.

Check shooting something:

if the pistol is not carried by the player:

say "You don't have a gun.";

stop the action;

otherwise if the shot count of the pistol is zero:

say "You're out of bullets.";

stop the action;

otherwise if the noun is not gunworthy:

say "There's no point. Save your bullets for something that needs them.";

stop the action;

otherwise if the noun is a person and the noun is dead:

say "He is already dead.";

stop the action.

Carry out shooting something:

decrease the shot count of the pistol by one.

[There are three different overlapping concepts here, all related to a level of concern, but all with different purposes in game. The vigilance has to do mostly with Krugnik, allowing him to look down the hallway. The panic level is mostly about the power outage. The discernment is all about the disguise.

There are places where the overlap might lead to bugs; for example, the fact that alarmed and panicked are two different states, but should probably not be.]

Vigilance is a kind of value. The vigilances are distracted, inattentive, alert, and suspicious.

Panic level is a kind of value. The panic levels are unconcerned, bothered, upset, and panicked.

Discernment is a kind of value. The discernments are ignorant, fooled, disturbed, and alarmed.

A guard is a kind of man. A guard can be alive or dead. A guard is usually alive. A guard has a vigilance. The vigilance of a guard is usually alert. A guard is always gunworthy.

An ordinary guard is a kind of guard. An ordinary guard has a panic level. An ordinary guard has a discernment. An ordinary guard is usually unconcerned and ignorant.

Understand "guard" as an ordinary guard. The printed name of an ordinary guard is "the[if dead]dead [end if] guard".

Instead of examining a guard (called the sentry):

if the sentry is alive:

if the sentry is unconcerned:

say "The guard gives you a glance. He seems to be [discernment].";

otherwise:

say "The guard is [panic level], and gives you a quick look that is more glare than glance.";

now the sentry is mentioned;

otherwise:

say "He's quite dead."

Instead of giving the secret papers to a guard (called the sentry):

if the sentry is dead:

say "He's not interested in anything, being dead.";

otherwise:

say "He accepts the papers with a frown, followed quickly by a double-take. He looks at you, eyes wide. 'These are the[unicode ellipsis]and you are[unicode ellipsis]the SPY!' he shrieks, and immediately shoots you through the heart.";

end the story finally.

This is the encountered guard rule:

if the player can see an ordinary guard (called the sentry) and the sentry is alive:

if the sentry is not unconcerned or the power is switched off:

now the the sentry is the panic level after the panic level of the sentry;

if the panic level of the sentry is bothered:

say "The guard is on edge in the wake of the power outage you caused. He is nervous and trigger-happy and staring wide-eyed into the dark. Fortunately he can't see your face yet, and he acknowledges you with a simple nod.";

otherwise if the panic level of the sentry is upset:

say "The guard's eyes seem to have adjusted to the dark. He sees your face, and his eyes grow wider still. [run paragraph on]";

now the sentry is panicked;

otherwise if the player is wearing the uniform:

if the sentry is ignorant:

if the sentry is not mentioned:

say "Looks like the guard isn't paying close attention to your face.";

otherwise if the sentry is fooled:

if the sentry is not mentioned:

say "Your disguise appears to be holding; the guard isn't suspicious yet.";

otherwise if the sentry is disturbed:

if the sentry is not mentioned:

say "Now the guard seems to be [if the sentry is not mentioned]a little disturbed, [end if]trying to get a good look at your face.";

otherwise if the sentry is alarmed:

say "The guard suddenly draws his weapon. 'You're not Krugnik! Who are you? And what have you done with him?' Startled, you make the fatal mistake of glancing up and making eye contact. [run paragraph on]";

now the sentry is panicked;

now the sentry is the discernment after the discernment of the sentry;

otherwise:

say "A look of shock comes over the guard's face as he sees you standing there in your ";

if the player is wearing the coveralls:

say "gloriously conspicuous prison coveralls, the bright orange triangle glowing like a beacon. Making a wonderful target.";

now the sentry is panicked;

otherwise:

say "your stunning nakedness.";

now the sentry is upset;

if the sentry is panicked:

say "'The SPY!' shrieks the guard, and before you can react, he has shot you conclusively through the heart.";

end the story finally.

The encountered guard rule is listed last in the every turn rulebook.

Instead of attacking a guard (called the target):

if the target is dead:

say "He's already plenty dead.";

otherwise if the pistol is carried by the player and the shot count of the pistol is greater than zero:

say "You use the gun. [run paragraph on]";

try shooting the target;

otherwise if the sharp piece of metal is carried by the player:

say "You use the piece of metal that worked so well before. Sadly, between a sharp piece of metal and a .38 caliber pistol, the firearm comes out on top. He perforates you soundly long before you get within striking distance.";

end the story finally;

otherwise:

say "You attack, your bare hands grasping for his throat. But this turns into a monumental failure as he triumphantly drills you through the skull with his sidearm.";

end the story finally.

Carry out shooting a guard (called the target):

say "You fire, point blank; he was not ready and you were. He is thrown against the far wall by the impact. He slumps to the ground, painting a bloody stripe down the wall behind him, his face frozen in a death mask of bewilderment.";

now the target is dead.